test.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use constant true => 1;
   6
   7 use File::Temp qw(tempfile tmpnam);
   8 use Test::More;
   9
  10 my $tests = 22;
  11
  12 my %BUF_SIZE = (
  13    normal => 1024,
  14    short  => 10,
  15 );
  16 my $source = 'colorize.c';
  17 my $warning_flags = '-Wall -Wextra -Wformat -Wswitch-default -Wuninitialized -Wunused -Wno-unused-function -Wno-unused-parameter';
  18
  19 my $write_to_tmpfile = sub
  20 {
  21     my ($content) = @_;
  22
  23     my ($fh, $tmpfile) = tempfile(UNLINK => true);
  24     print {$fh} $content;
  25     close($fh);
  26
  27     return $tmpfile;
  28 };
  29
  30 plan tests => $tests;
  31
  32 SKIP: {
  33     skip "$source does not exist", $tests unless -e $source;
  34
  35     my $program = tmpnam();
  36     skip 'compiling failed (normal)', $tests unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{normal} $warning_flags -o $program $source") == 0;
  37
  38     is(system("$program --help >/dev/null 2>&1"), 0, 'exit value for help screen');
  39
  40     is(qx(echo    "hello world" | $program none/none), "hello world\n", 'line read from stdin with newline');
  41     is(qx(echo -n "hello world" | $program none/none), "hello world",   'line read from stdin without newline');
  42
  43     my $text = do { local $/; <DATA> };
  44
  45     my $infile1 = $write_to_tmpfile->($text);
  46
  47     is_deeply([split /\n/, qx(cat $infile1 | $program none/none)], [split /\n/, $text], 'text read from stdin');
  48     is_deeply([split /\n/, qx($program none/none $infile1)],       [split /\n/, $text], 'text read from file');
  49
  50     {
  51         my @fg_colors = (30..37, 39);
  52         my @bg_colors = (40..47, 49);
  53
  54         my @bold_colors = map "1;$_", @fg_colors;
  55
  56         my @values = (@fg_colors, @bg_colors, @bold_colors, 0);
  57
  58         my $ok = true;
  59         foreach my $value (@values) {
  60             $ok &= qx(echo -n "\e[${value}m" | $program --clean) eq '';
  61         }
  62         ok($ok, 'clean color sequences');
  63     }
  64
  65     my $check_clean = sub
  66     {
  67         my ($type) = @_;
  68
  69         my $switch = "--$type";
  70
  71         is(qx(echo -n "\e[35mhello\e[0m \e[36mworld\e[0m" | $program $switch),       'hello world', "$type colored words");
  72         is(qx(echo -n "hello world" | $program Magenta | $program $switch),          'hello world', "$type colored line");
  73         is_deeply([split /\n/, qx($program cyan $infile1 | $program $switch)], [split /\n/, $text], "$type colored text");
  74
  75         ok(qx(echo -n "\e[\e[33m" | $program $switch) eq "\e[", "$type with invalid sequence");
  76     };
  77
  78     $check_clean->($_) foreach qw(clean clean-all);
  79
  80     is(qx(echo -n "\e[4munderline\e[24m" | $program --clean-all), 'underline', 'clean-all color sequences');
  81
  82     my $check_clean_buf = sub
  83     {
  84         my ($program_buf, $type) = @_;
  85
  86         my $switch = "--$type";
  87
  88         # Check that line chunks are merged when cleaning text
  89         my $short_text = 'Linux dev 2.6.32-5-openvz-686 #1 SMP Sun Sep 23 11:40:07 UTC 2012 i686 GNU/Linux';
  90         is(qx(echo -n "$short_text" | $program_buf $switch), $short_text, "merge ${\length $short_text} bytes (BUF_SIZE=$BUF_SIZE{short}, $type)");
  91     };
  92
  93     SKIP: {
  94         my $program_buf = tmpnam();
  95         skip 'compiling failed (short buffer)', 2 unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{short} $warning_flags -o $program_buf $source") == 0;
  96         $check_clean_buf->($program_buf, $_) foreach qw(clean clean-all);
  97         unlink $program_buf;
  98     }
  99
 100     my $repeated = join "\n", ($text) x 7;
 101     my $infile2  = $write_to_tmpfile->($repeated);
 102
 103     is_deeply([split /\n/, qx(cat $infile2 | $program none/none)], [split /\n/, $repeated], "read ${\length $repeated} bytes (BUF_SIZE=$BUF_SIZE{normal})");
 104
 105     my $colored_text = qx(echo "foo bar baz" | $program red);
 106     my $sequences = 0;
 107     $sequences++ while $colored_text =~ /\e\[\d+m/g;
 108     is($sequences, 2, 'count of sequences printed');
 109
 110     is(qx(echo -n "hello\nworld\r\n" | $program none/none), "hello\nworld\r\n", 'stream mode');
 111
 112     is(system("echo \"hello world\" | $program random --exclude-random=black >/dev/null 2>&1"), 0, 'switch exclude-random');
 113
 114     SKIP: {
 115         skip 'valgrind not found', 1 unless system('which valgrind >/dev/null 2>&1') == 0;
 116         like(qx(valgrind $program none/none $infile1 2>&1 >/dev/null), qr/no leaks are possible/, 'valgrind memleaks');
 117     }
 118
 119     print <<'EOT';
 120 Colors
 121 ======
 122 EOT
 123     foreach my $color (qw(none black red green yellow blue cyan magenta white default random)) {
 124         system("echo $color | $program $color");
 125         next if $color eq 'none';
 126         my $bold_color = ucfirst $color;
 127         system("echo $bold_color | $program $bold_color");
 128     }
 129
 130     unlink $program;
 131 };
 132
 133 __DATA__
 134 Lorem ipsum dolor sit amet, consectetur adipiscing elit. Vivamus urna mauris, ultricies faucibus placerat sit amet, rutrum eu
 135 nisi. Quisque dictum turpis non augue iaculis tincidunt nec a arcu. Donec euismod sapien ac dui blandit et adipiscing risus
 136 semper. Sed ornare ligula magna, vitae molestie eros. Praesent ligula est, euismod a luctus non, porttitor quis nunc. Fusce vel
 137 imperdiet turpis. Proin vitae mauris neque, fringilla vestibulum sapien. Pellentesque vitae nibh ipsum, non cursus diam. Cras
 138 vitae ligula mauris. Etiam tortor enim, varius nec adipiscing sed, lobortis et quam. Quisque convallis, diam sagittis adipiscing
 139 adipiscing, mi nibh fermentum sapien, et iaculis nisi sem sit amet odio. Cras a tortor at nibh tristique vehicula dapibus eu velit.
 140
 141 Vivamus porttitor purus eget leo suscipit sed posuere ligula gravida. In mollis velit quis leo pharetra gravida. Ut libero nisi,
 142 elementum sed varius tincidunt, hendrerit ut dui. Duis sit amet ante eget velit dictum ultrices. Nulla tempus, lacus eu dignissim
 143 feugiat, turpis mauris volutpat urna, quis commodo lorem augue id justo. Aenean consequat interdum sapien, sit amet
 144 imperdiet ante dapibus at. Pellentesque viverra sagittis tincidunt. Quisque rhoncus varius magna, sit amet rutrum arcu
 145 tincidunt eget. Etiam a lacus nec mauris interdum luctus sed in lacus. Ut pulvinar, augue at dictum blandit, nisl massa pretium
 146 ligula, in iaculis nulla nisi iaculis nunc.
 147
 148 Vivamus id eros nunc. Cras facilisis iaculis ante sit amet consequat. Nunc vehicula imperdiet sem, ac vehicula neque
 149 condimentum sed. Phasellus metus lacus, molestie ullamcorper imperdiet in, condimentum ut tellus. Nullam dignissim dui ut
 150 enim ullamcorper in tempus risus posuere. Ut volutpat enim eleifend diam convallis tristique. Proin porttitor augue sed sapien
 151 sagittis quis facilisis purus sodales. Integer auctor dolor rhoncus nisl consequat adipiscing. Aliquam eget ante sit amet quam
 152 porta eleifend.