test.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use constant true  => 1;
   6 use constant false => 0;
   7
   8 use File::Temp qw(tempfile tempdir tmpnam);
   9 use IPC::Open3 qw(open3);
  10 use Symbol qw(gensym);
  11 use Test::Harness qw(runtests);
  12 use Test::More;
  13
  14 my $tests = 25;
  15
  16 my %BUF_SIZE = (
  17    normal => 1024,
  18    short  => 10,
  19 );
  20 my $source = 'colorize.c';
  21 my $compiler_flags = '-ansi -pedantic -Wall -Wextra -Wformat -Wswitch-default -Wuninitialized -Wunused -Wno-unused-function -Wno-unused-parameter';
  22
  23 my $write_to_tmpfile = sub
  24 {
  25     my ($content) = @_;
  26
  27     my ($fh, $tmpfile) = tempfile(UNLINK => true);
  28     print {$fh} $content;
  29     close($fh);
  30
  31     return $tmpfile;
  32 };
  33
  34 {
  35     my @test_files = glob('t/*.t');
  36     runtests(@test_files);
  37 }
  38
  39 plan tests => $tests;
  40
  41 SKIP: {
  42     skip "$source does not exist", $tests unless -e $source;
  43
  44     my $binary = tmpnam();
  45     skip 'compiling failed', $tests unless system("gcc $compiler_flags -o $binary $source") == 0;
  46     unlink $binary;
  47
  48     my $program = tmpnam();
  49     skip 'compiling failed (normal)', $tests unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{normal} -o $program $source") == 0;
  50
  51     is(system("$program --help >/dev/null 2>&1"),    0, 'exit value for help screen');
  52     is(system("$program --version >/dev/null 2>&1"), 0, 'exit value for version data');
  53
  54     my $run_program_fail = sub
  55     {
  56         my ($program, $args, $message) = @_;
  57
  58         my @args = split /\s+/, $args;
  59
  60         my $err = gensym;
  61
  62         my $pid = open3(gensym, gensym, $err, $program, @args);
  63         waitpid($pid, 0);
  64
  65         my $output = do { local $/; <$err> };
  66
  67         return ($? >> 8 == 1 && $output =~ /$message/) ? true : false;
  68     };
  69
  70     {
  71         my $ok = true;
  72
  73         my $file = $write_to_tmpfile->('abc');
  74         my $dir  = tempdir(CLEANUP => true);
  75
  76         $ok &= $run_program_fail->($program, '--exclude-random=random', 'must be provided a plain color');
  77         $ok &= $run_program_fail->($program, '--clean --clean-all',     'mutually exclusive');
  78         $ok &= $run_program_fail->($program, '--clean file1 file2',     'more than one file');
  79         $ok &= $run_program_fail->($program, '--clean-all file1 file2', 'more than one file');
  80         $ok &= $run_program_fail->($program, '- file',                  'hyphen cannot be used as color string');
  81         $ok &= $run_program_fail->($program, '-',                       'hyphen must be preceeded by color string');
  82         $ok &= $run_program_fail->($program, "$file file",              'cannot be used as color string');
  83         $ok &= $run_program_fail->($program, "$file",                   'must be preceeded by color string');
  84         $ok &= $run_program_fail->($program, "$dir",                    'is not a valid file type');
  85         $ok &= $run_program_fail->($program, '/black',                  'foreground color missing');
  86         $ok &= $run_program_fail->($program, 'white/',                  'background color missing');
  87         $ok &= $run_program_fail->($program, 'white/black/yellow',      'one color pair allowed only');
  88         $ok &= $run_program_fail->($program, 'y3llow',                  'cannot be made of non-alphabetic characters');
  89         $ok &= $run_program_fail->($program, 'yEllow',                  'cannot be in mixed lower/upper case');
  90         $ok &= $run_program_fail->($program, 'None',                    'cannot be bold');
  91         $ok &= $run_program_fail->($program, 'white/Black',             'cannot be bold');
  92
  93         foreach my $color_pair (qw(random/none random/default none/random default/random)) {
  94             $ok &= $run_program_fail->($program, $color_pair, 'cannot be combined with');
  95         }
  96
  97         ok($ok, 'exit messages/values for failures');
  98     }
  99
 100     is(qx(echo    "hello world" | $program none/none), "hello world\n", 'line read from stdin with newline');
 101     is(qx(echo -n "hello world" | $program none/none), "hello world",   'line read from stdin without newline');
 102
 103     my $text = do { local $/; <DATA> };
 104
 105     my $infile1 = $write_to_tmpfile->($text);
 106
 107     is_deeply([split /\n/, qx(cat $infile1 | $program none/none)], [split /\n/, $text], 'text read from stdin');
 108     is_deeply([split /\n/, qx($program none/none $infile1)],       [split /\n/, $text], 'text read from file');
 109
 110     {
 111         my @fg_colors = (30..37, 39);
 112         my @bg_colors = (40..47, 49);
 113
 114         my @bold_colors = map "1;$_", @fg_colors;
 115
 116         my @values = (@fg_colors, @bg_colors, @bold_colors, 0);
 117
 118         my $ok = true;
 119         foreach my $value (@values) {
 120             $ok &= qx(echo -n "\e[${value}m" | $program --clean) eq '';
 121         }
 122         ok($ok, 'clean color sequences');
 123     }
 124
 125     my $check_clean = sub
 126     {
 127         my ($type) = @_;
 128
 129         my $switch = "--$type";
 130
 131         is(qx(echo -n "\e[35mhello\e[0m \e[36mworld\e[0m" | $program $switch),       'hello world', "$type colored words");
 132         is(qx(echo -n "hello world" | $program Magenta | $program $switch),          'hello world', "$type colored line");
 133         is_deeply([split /\n/, qx($program cyan $infile1 | $program $switch)], [split /\n/, $text], "$type colored text");
 134
 135         ok(qx(echo -n "\e[\e[33m" | $program $switch) eq "\e[", "$type with invalid sequence");
 136     };
 137
 138     $check_clean->($_) foreach qw(clean clean-all);
 139
 140     is(qx(echo -n "\e[4munderline\e[24m" | $program --clean-all), 'underline', 'clean-all color sequences');
 141
 142     my $check_clean_buf = sub
 143     {
 144         my ($program_buf, $type) = @_;
 145
 146         my $switch = "--$type";
 147
 148         # Check that line chunks are printed when cleaning text without sequences
 149         my $short_text = 'Linux dev 2.6.32-5-openvz-686 #1 SMP Sun Sep 23 11:40:07 UTC 2012 i686 GNU/Linux';
 150         is(qx(echo -n "$short_text" | $program_buf $switch), $short_text, "print ${\length $short_text} bytes (BUF_SIZE=$BUF_SIZE{short}, $type)");
 151     };
 152
 153     SKIP: {
 154         my $program_buf = tmpnam();
 155         skip 'compiling failed (short buffer)', 2 unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{short} -o $program_buf $source") == 0;
 156         $check_clean_buf->($program_buf, $_) foreach qw(clean clean-all);
 157         unlink $program_buf;
 158     }
 159
 160     my $repeated = join "\n", ($text) x 7;
 161     my $infile2  = $write_to_tmpfile->($repeated);
 162
 163     is_deeply([split /\n/, qx(cat $infile2 | $program none/none)], [split /\n/, $repeated], "read ${\length $repeated} bytes (BUF_SIZE=$BUF_SIZE{normal})");
 164
 165     {
 166         my $colored_text = qx(echo "foo bar baz" | $program red);
 167         my $sequences = 0;
 168         $sequences++ while $colored_text =~ /\e\[\d+m/g;
 169         is($sequences, 2, 'count of sequences printed');
 170     }
 171
 172     is(qx(echo -n "hello\nworld\r\n" | $program none/none), "hello\nworld\r\n", 'stream mode');
 173
 174     is(system("echo \"hello world\" | $program random --exclude-random=black >/dev/null 2>&1"), 0, 'switch exclude-random');
 175
 176     SKIP: {
 177         skip 'valgrind not found', 1 unless system('which valgrind >/dev/null 2>&1') == 0;
 178         like(qx(valgrind $program none/none $infile1 2>&1 >/dev/null), qr/no leaks are possible/, 'valgrind memleaks');
 179     }
 180
 181     {
 182         my $debug = tmpnam();
 183         is(system("gcc -DDEBUG -o $debug $source"), 0, 'debugging build');
 184         unlink $debug if -e $debug;
 185     }
 186
 187     print <<'EOT';
 188 Colors
 189 ======
 190 EOT
 191     foreach my $color (qw(none black red green yellow blue magenta cyan white default random)) {
 192         system("echo $color | $program $color");
 193         next if $color eq 'none';
 194         my $bold_color = ucfirst $color;
 195         system("echo $bold_color | $program $bold_color");
 196     }
 197
 198     unlink $program;
 199 };
 200
 201 __DATA__
 202 Lorem ipsum dolor sit amet, consectetur adipiscing elit. Vivamus urna mauris, ultricies faucibus placerat sit amet, rutrum eu
 203 nisi. Quisque dictum turpis non augue iaculis tincidunt nec a arcu. Donec euismod sapien ac dui blandit et adipiscing risus
 204 semper. Sed ornare ligula magna, vitae molestie eros. Praesent ligula est, euismod a luctus non, porttitor quis nunc. Fusce vel
 205 imperdiet turpis. Proin vitae mauris neque, fringilla vestibulum sapien. Pellentesque vitae nibh ipsum, non cursus diam. Cras
 206 vitae ligula mauris. Etiam tortor enim, varius nec adipiscing sed, lobortis et quam. Quisque convallis, diam sagittis adipiscing
 207 adipiscing, mi nibh fermentum sapien, et iaculis nisi sem sit amet odio. Cras a tortor at nibh tristique vehicula dapibus eu velit.
 208
 209 Vivamus porttitor purus eget leo suscipit sed posuere ligula gravida. In mollis velit quis leo pharetra gravida. Ut libero nisi,
 210 elementum sed varius tincidunt, hendrerit ut dui. Duis sit amet ante eget velit dictum ultrices. Nulla tempus, lacus eu dignissim
 211 feugiat, turpis mauris volutpat urna, quis commodo lorem augue id justo. Aenean consequat interdum sapien, sit amet
 212 imperdiet ante dapibus at. Pellentesque viverra sagittis tincidunt. Quisque rhoncus varius magna, sit amet rutrum arcu
 213 tincidunt eget. Etiam a lacus nec mauris interdum luctus sed in lacus. Ut pulvinar, augue at dictum blandit, nisl massa pretium
 214 ligula, in iaculis nulla nisi iaculis nunc.
 215
 216 Vivamus id eros nunc. Cras facilisis iaculis ante sit amet consequat. Nunc vehicula imperdiet sem, ac vehicula neque
 217 condimentum sed. Phasellus metus lacus, molestie ullamcorper imperdiet in, condimentum ut tellus. Nullam dignissim dui ut
 218 enim ullamcorper in tempus risus posuere. Ut volutpat enim eleifend diam convallis tristique. Proin porttitor augue sed sapien
 219 sagittis quis facilisis purus sodales. Integer auctor dolor rhoncus nisl consequat adipiscing. Aliquam eget ante sit amet quam
 220 porta eleifend.