test.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use constant true  => 1;
   6 use constant false => 0;
   7
   8 use File::Temp qw(tempfile tempdir tmpnam);
   9 use IPC::Open3 qw(open3);
  10 use Symbol qw(gensym);
  11 use Test::More;
  12
  13 my $tests = 23;
  14
  15 my %BUF_SIZE = (
  16    normal => 1024,
  17    short  => 10,
  18 );
  19 my $source = 'colorize.c';
  20 my $compiler_flags = '-ansi -pedantic -Wall -Wextra -Wformat -Wswitch-default -Wuninitialized -Wunused -Wno-unused-function -Wno-unused-parameter';
  21
  22 my $write_to_tmpfile = sub
  23 {
  24     my ($content) = @_;
  25
  26     my ($fh, $tmpfile) = tempfile(UNLINK => true);
  27     print {$fh} $content;
  28     close($fh);
  29
  30     return $tmpfile;
  31 };
  32
  33 plan tests => $tests;
  34
  35 SKIP: {
  36     skip "$source does not exist", $tests unless -e $source;
  37
  38     my $binary = tmpnam();
  39     skip 'compiling failed', $tests unless system("gcc $compiler_flags -o $binary $source") == 0;
  40     unlink $binary;
  41
  42     my $program = tmpnam();
  43     skip 'compiling failed (normal)', $tests unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{normal} -o $program $source") == 0;
  44
  45     is(system("$program --help >/dev/null 2>&1"), 0, 'exit value for help screen');
  46
  47     my $run_program_fail = sub
  48     {
  49         my ($program, $args, $message) = @_;
  50
  51         my @args = split /\s+/, $args;
  52
  53         my $err = gensym;
  54
  55         my $pid = open3(gensym, gensym, $err, $program, @args);
  56         waitpid($pid, 0);
  57
  58         my $output = do { local $/; <$err> };
  59
  60         return ($? >> 8 == 1 && $output =~ /$message/) ? true : false;
  61     };
  62
  63     {
  64         my $ok = true;
  65
  66         my $file = $write_to_tmpfile->('abc');
  67         my $dir  = tempdir(CLEANUP => true);
  68
  69         $ok &= $run_program_fail->($program, '--exclude-random=random', 'must be provided a plain color');
  70         $ok &= $run_program_fail->($program, '--clean --clean-all',     'mutually exclusive');
  71         $ok &= $run_program_fail->($program, '--clean file1 file2',     'more than one file');
  72         $ok &= $run_program_fail->($program, '--clean-all file1 file2', 'more than one file');
  73         $ok &= $run_program_fail->($program, '- file',                  'hyphen cannot be used as color string');
  74         $ok &= $run_program_fail->($program, '-',                       'hyphen must be preceeded by color string');
  75         $ok &= $run_program_fail->($program, "$file file",              'cannot be used as color string');
  76         $ok &= $run_program_fail->($program, "$file",                   'must be preceeded by color string');
  77         $ok &= $run_program_fail->($program, "$dir",                    'is not a valid file type');
  78         $ok &= $run_program_fail->($program, '/black',                  'foreground color missing');
  79         $ok &= $run_program_fail->($program, 'white/',                  'background color missing');
  80         $ok &= $run_program_fail->($program, 'white/black/yellow',      'one color pair allowed only');
  81         $ok &= $run_program_fail->($program, 'y3llow',                  'cannot be made of non-alphabetic characters');
  82         $ok &= $run_program_fail->($program, 'yEllow',                  'cannot be in mixed lower/upper case');
  83         $ok &= $run_program_fail->($program, 'None',                    'cannot be bold');
  84         $ok &= $run_program_fail->($program, 'white/Black',             'cannot be bold');
  85
  86         foreach my $color_pair (qw(random/none random/default none/random default/random)) {
  87             $ok &= $run_program_fail->($program, $color_pair, 'cannot be combined with');
  88         }
  89
  90         ok($ok, 'exit messages/values for failures');
  91     }
  92
  93     is(qx(echo    "hello world" | $program none/none), "hello world\n", 'line read from stdin with newline');
  94     is(qx(echo -n "hello world" | $program none/none), "hello world",   'line read from stdin without newline');
  95
  96     my $text = do { local $/; <DATA> };
  97
  98     my $infile1 = $write_to_tmpfile->($text);
  99
 100     is_deeply([split /\n/, qx(cat $infile1 | $program none/none)], [split /\n/, $text], 'text read from stdin');
 101     is_deeply([split /\n/, qx($program none/none $infile1)],       [split /\n/, $text], 'text read from file');
 102
 103     {
 104         my @fg_colors = (30..37, 39);
 105         my @bg_colors = (40..47, 49);
 106
 107         my @bold_colors = map "1;$_", @fg_colors;
 108
 109         my @values = (@fg_colors, @bg_colors, @bold_colors, 0);
 110
 111         my $ok = true;
 112         foreach my $value (@values) {
 113             $ok &= qx(echo -n "\e[${value}m" | $program --clean) eq '';
 114         }
 115         ok($ok, 'clean color sequences');
 116     }
 117
 118     my $check_clean = sub
 119     {
 120         my ($type) = @_;
 121
 122         my $switch = "--$type";
 123
 124         is(qx(echo -n "\e[35mhello\e[0m \e[36mworld\e[0m" | $program $switch),       'hello world', "$type colored words");
 125         is(qx(echo -n "hello world" | $program Magenta | $program $switch),          'hello world', "$type colored line");
 126         is_deeply([split /\n/, qx($program cyan $infile1 | $program $switch)], [split /\n/, $text], "$type colored text");
 127
 128         ok(qx(echo -n "\e[\e[33m" | $program $switch) eq "\e[", "$type with invalid sequence");
 129     };
 130
 131     $check_clean->($_) foreach qw(clean clean-all);
 132
 133     is(qx(echo -n "\e[4munderline\e[24m" | $program --clean-all), 'underline', 'clean-all color sequences');
 134
 135     my $check_clean_buf = sub
 136     {
 137         my ($program_buf, $type) = @_;
 138
 139         my $switch = "--$type";
 140
 141         # Check that line chunks are merged when cleaning text
 142         my $short_text = 'Linux dev 2.6.32-5-openvz-686 #1 SMP Sun Sep 23 11:40:07 UTC 2012 i686 GNU/Linux';
 143         is(qx(echo -n "$short_text" | $program_buf $switch), $short_text, "merge ${\length $short_text} bytes (BUF_SIZE=$BUF_SIZE{short}, $type)");
 144     };
 145
 146     SKIP: {
 147         my $program_buf = tmpnam();
 148         skip 'compiling failed (short buffer)', 2 unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{short} -o $program_buf $source") == 0;
 149         $check_clean_buf->($program_buf, $_) foreach qw(clean clean-all);
 150         unlink $program_buf;
 151     }
 152
 153     my $repeated = join "\n", ($text) x 7;
 154     my $infile2  = $write_to_tmpfile->($repeated);
 155
 156     is_deeply([split /\n/, qx(cat $infile2 | $program none/none)], [split /\n/, $repeated], "read ${\length $repeated} bytes (BUF_SIZE=$BUF_SIZE{normal})");
 157
 158     {
 159         my $colored_text = qx(echo "foo bar baz" | $program red);
 160         my $sequences = 0;
 161         $sequences++ while $colored_text =~ /\e\[\d+m/g;
 162         is($sequences, 2, 'count of sequences printed');
 163     }
 164
 165     is(qx(echo -n "hello\nworld\r\n" | $program none/none), "hello\nworld\r\n", 'stream mode');
 166
 167     is(system("echo \"hello world\" | $program random --exclude-random=black >/dev/null 2>&1"), 0, 'switch exclude-random');
 168
 169     SKIP: {
 170         skip 'valgrind not found', 1 unless system('which valgrind >/dev/null 2>&1') == 0;
 171         like(qx(valgrind $program none/none $infile1 2>&1 >/dev/null), qr/no leaks are possible/, 'valgrind memleaks');
 172     }
 173
 174     print <<'EOT';
 175 Colors
 176 ======
 177 EOT
 178     foreach my $color (qw(none black red green yellow blue magenta cyan white default random)) {
 179         system("echo $color | $program $color");
 180         next if $color eq 'none';
 181         my $bold_color = ucfirst $color;
 182         system("echo $bold_color | $program $bold_color");
 183     }
 184
 185     unlink $program;
 186 };
 187
 188 __DATA__
 189 Lorem ipsum dolor sit amet, consectetur adipiscing elit. Vivamus urna mauris, ultricies faucibus placerat sit amet, rutrum eu
 190 nisi. Quisque dictum turpis non augue iaculis tincidunt nec a arcu. Donec euismod sapien ac dui blandit et adipiscing risus
 191 semper. Sed ornare ligula magna, vitae molestie eros. Praesent ligula est, euismod a luctus non, porttitor quis nunc. Fusce vel
 192 imperdiet turpis. Proin vitae mauris neque, fringilla vestibulum sapien. Pellentesque vitae nibh ipsum, non cursus diam. Cras
 193 vitae ligula mauris. Etiam tortor enim, varius nec adipiscing sed, lobortis et quam. Quisque convallis, diam sagittis adipiscing
 194 adipiscing, mi nibh fermentum sapien, et iaculis nisi sem sit amet odio. Cras a tortor at nibh tristique vehicula dapibus eu velit.
 195
 196 Vivamus porttitor purus eget leo suscipit sed posuere ligula gravida. In mollis velit quis leo pharetra gravida. Ut libero nisi,
 197 elementum sed varius tincidunt, hendrerit ut dui. Duis sit amet ante eget velit dictum ultrices. Nulla tempus, lacus eu dignissim
 198 feugiat, turpis mauris volutpat urna, quis commodo lorem augue id justo. Aenean consequat interdum sapien, sit amet
 199 imperdiet ante dapibus at. Pellentesque viverra sagittis tincidunt. Quisque rhoncus varius magna, sit amet rutrum arcu
 200 tincidunt eget. Etiam a lacus nec mauris interdum luctus sed in lacus. Ut pulvinar, augue at dictum blandit, nisl massa pretium
 201 ligula, in iaculis nulla nisi iaculis nunc.
 202
 203 Vivamus id eros nunc. Cras facilisis iaculis ante sit amet consequat. Nunc vehicula imperdiet sem, ac vehicula neque
 204 condimentum sed. Phasellus metus lacus, molestie ullamcorper imperdiet in, condimentum ut tellus. Nullam dignissim dui ut
 205 enim ullamcorper in tempus risus posuere. Ut volutpat enim eleifend diam convallis tristique. Proin porttitor augue sed sapien
 206 sagittis quis facilisis purus sodales. Integer auctor dolor rhoncus nisl consequat adipiscing. Aliquam eget ante sit amet quam
 207 porta eleifend.