test.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use constant true  => 1;
   6 use constant false => 0;
   7
   8 use File::Temp qw(tempfile tempdir tmpnam);
   9 use IPC::Open3 qw(open3);
  10 use Symbol qw(gensym);
  11 use Test::More;
  12
  13 my $tests = 25;
  14
  15 my %BUF_SIZE = (
  16    normal => 1024,
  17    short  => 10,
  18 );
  19 my $source = 'colorize.c';
  20 my $compiler_flags = '-ansi -pedantic -Wall -Wextra -Wformat -Wswitch-default -Wuninitialized -Wunused -Wno-unused-function -Wno-unused-parameter';
  21
  22 my $write_to_tmpfile = sub
  23 {
  24     my ($content) = @_;
  25
  26     my ($fh, $tmpfile) = tempfile(UNLINK => true);
  27     print {$fh} $content;
  28     close($fh);
  29
  30     return $tmpfile;
  31 };
  32
  33 plan tests => $tests;
  34
  35 SKIP: {
  36     skip "$source does not exist", $tests unless -e $source;
  37
  38     my $binary = tmpnam();
  39     skip 'compiling failed', $tests unless system("gcc $compiler_flags -o $binary $source") == 0;
  40     unlink $binary;
  41
  42     my $program = tmpnam();
  43     skip 'compiling failed (normal)', $tests unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{normal} -o $program $source") == 0;
  44
  45     is(system("$program --help >/dev/null 2>&1"),    0, 'exit value for help screen');
  46     is(system("$program --version >/dev/null 2>&1"), 0, 'exit value for version data');
  47
  48     my $run_program_fail = sub
  49     {
  50         my ($program, $args, $message) = @_;
  51
  52         my @args = split /\s+/, $args;
  53
  54         my $err = gensym;
  55
  56         my $pid = open3(gensym, gensym, $err, $program, @args);
  57         waitpid($pid, 0);
  58
  59         my $output = do { local $/; <$err> };
  60
  61         return ($? >> 8 == 1 && $output =~ /$message/) ? true : false;
  62     };
  63
  64     {
  65         my $ok = true;
  66
  67         my $file = $write_to_tmpfile->('abc');
  68         my $dir  = tempdir(CLEANUP => true);
  69
  70         $ok &= $run_program_fail->($program, '--exclude-random=random', 'must be provided a plain color');
  71         $ok &= $run_program_fail->($program, '--clean --clean-all',     'mutually exclusive');
  72         $ok &= $run_program_fail->($program, '--clean file1 file2',     'more than one file');
  73         $ok &= $run_program_fail->($program, '--clean-all file1 file2', 'more than one file');
  74         $ok &= $run_program_fail->($program, '- file',                  'hyphen cannot be used as color string');
  75         $ok &= $run_program_fail->($program, '-',                       'hyphen must be preceeded by color string');
  76         $ok &= $run_program_fail->($program, "$file file",              'cannot be used as color string');
  77         $ok &= $run_program_fail->($program, "$file",                   'must be preceeded by color string');
  78         $ok &= $run_program_fail->($program, "$dir",                    'is not a valid file type');
  79         $ok &= $run_program_fail->($program, '/black',                  'foreground color missing');
  80         $ok &= $run_program_fail->($program, 'white/',                  'background color missing');
  81         $ok &= $run_program_fail->($program, 'white/black/yellow',      'one color pair allowed only');
  82         $ok &= $run_program_fail->($program, 'y3llow',                  'cannot be made of non-alphabetic characters');
  83         $ok &= $run_program_fail->($program, 'yEllow',                  'cannot be in mixed lower/upper case');
  84         $ok &= $run_program_fail->($program, 'None',                    'cannot be bold');
  85         $ok &= $run_program_fail->($program, 'white/Black',             'cannot be bold');
  86
  87         foreach my $color_pair (qw(random/none random/default none/random default/random)) {
  88             $ok &= $run_program_fail->($program, $color_pair, 'cannot be combined with');
  89         }
  90
  91         ok($ok, 'exit messages/values for failures');
  92     }
  93
  94     is(qx(echo    "hello world" | $program none/none), "hello world\n", 'line read from stdin with newline');
  95     is(qx(echo -n "hello world" | $program none/none), "hello world",   'line read from stdin without newline');
  96
  97     my $text = do { local $/; <DATA> };
  98
  99     my $infile1 = $write_to_tmpfile->($text);
 100
 101     is_deeply([split /\n/, qx(cat $infile1 | $program none/none)], [split /\n/, $text], 'text read from stdin');
 102     is_deeply([split /\n/, qx($program none/none $infile1)],       [split /\n/, $text], 'text read from file');
 103
 104     {
 105         my @fg_colors = (30..37, 39);
 106         my @bg_colors = (40..47, 49);
 107
 108         my @bold_colors = map "1;$_", @fg_colors;
 109
 110         my @values = (@fg_colors, @bg_colors, @bold_colors, 0);
 111
 112         my $ok = true;
 113         foreach my $value (@values) {
 114             $ok &= qx(echo -n "\e[${value}m" | $program --clean) eq '';
 115         }
 116         ok($ok, 'clean color sequences');
 117     }
 118
 119     my $check_clean = sub
 120     {
 121         my ($type) = @_;
 122
 123         my $switch = "--$type";
 124
 125         is(qx(echo -n "\e[35mhello\e[0m \e[36mworld\e[0m" | $program $switch),       'hello world', "$type colored words");
 126         is(qx(echo -n "hello world" | $program Magenta | $program $switch),          'hello world', "$type colored line");
 127         is_deeply([split /\n/, qx($program cyan $infile1 | $program $switch)], [split /\n/, $text], "$type colored text");
 128
 129         ok(qx(echo -n "\e[\e[33m" | $program $switch) eq "\e[", "$type with invalid sequence");
 130     };
 131
 132     $check_clean->($_) foreach qw(clean clean-all);
 133
 134     is(qx(echo -n "\e[4munderline\e[24m" | $program --clean-all), 'underline', 'clean-all color sequences');
 135
 136     my $check_clean_buf = sub
 137     {
 138         my ($program_buf, $type) = @_;
 139
 140         my $switch = "--$type";
 141
 142         # Check that line chunks are merged when cleaning text
 143         my $short_text = 'Linux dev 2.6.32-5-openvz-686 #1 SMP Sun Sep 23 11:40:07 UTC 2012 i686 GNU/Linux';
 144         is(qx(echo -n "$short_text" | $program_buf $switch), $short_text, "merge ${\length $short_text} bytes (BUF_SIZE=$BUF_SIZE{short}, $type)");
 145     };
 146
 147     SKIP: {
 148         my $program_buf = tmpnam();
 149         skip 'compiling failed (short buffer)', 2 unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{short} -o $program_buf $source") == 0;
 150         $check_clean_buf->($program_buf, $_) foreach qw(clean clean-all);
 151         unlink $program_buf;
 152     }
 153
 154     my $repeated = join "\n", ($text) x 7;
 155     my $infile2  = $write_to_tmpfile->($repeated);
 156
 157     is_deeply([split /\n/, qx(cat $infile2 | $program none/none)], [split /\n/, $repeated], "read ${\length $repeated} bytes (BUF_SIZE=$BUF_SIZE{normal})");
 158
 159     {
 160         my $colored_text = qx(echo "foo bar baz" | $program red);
 161         my $sequences = 0;
 162         $sequences++ while $colored_text =~ /\e\[\d+m/g;
 163         is($sequences, 2, 'count of sequences printed');
 164     }
 165
 166     is(qx(echo -n "hello\nworld\r\n" | $program none/none), "hello\nworld\r\n", 'stream mode');
 167
 168     is(system("echo \"hello world\" | $program random --exclude-random=black >/dev/null 2>&1"), 0, 'switch exclude-random');
 169
 170     SKIP: {
 171         skip 'valgrind not found', 1 unless system('which valgrind >/dev/null 2>&1') == 0;
 172         like(qx(valgrind $program none/none $infile1 2>&1 >/dev/null), qr/no leaks are possible/, 'valgrind memleaks');
 173     }
 174
 175     {
 176         my $debug = tmpnam();
 177         is(system("gcc -DDEBUG -o $debug $source"), 0, 'debugging build');
 178         unlink $debug if -e $debug;
 179     }
 180
 181     print <<'EOT';
 182 Colors
 183 ======
 184 EOT
 185     foreach my $color (qw(none black red green yellow blue magenta cyan white default random)) {
 186         system("echo $color | $program $color");
 187         next if $color eq 'none';
 188         my $bold_color = ucfirst $color;
 189         system("echo $bold_color | $program $bold_color");
 190     }
 191
 192     unlink $program;
 193 };
 194
 195 __DATA__
 196 Lorem ipsum dolor sit amet, consectetur adipiscing elit. Vivamus urna mauris, ultricies faucibus placerat sit amet, rutrum eu
 197 nisi. Quisque dictum turpis non augue iaculis tincidunt nec a arcu. Donec euismod sapien ac dui blandit et adipiscing risus
 198 semper. Sed ornare ligula magna, vitae molestie eros. Praesent ligula est, euismod a luctus non, porttitor quis nunc. Fusce vel
 199 imperdiet turpis. Proin vitae mauris neque, fringilla vestibulum sapien. Pellentesque vitae nibh ipsum, non cursus diam. Cras
 200 vitae ligula mauris. Etiam tortor enim, varius nec adipiscing sed, lobortis et quam. Quisque convallis, diam sagittis adipiscing
 201 adipiscing, mi nibh fermentum sapien, et iaculis nisi sem sit amet odio. Cras a tortor at nibh tristique vehicula dapibus eu velit.
 202
 203 Vivamus porttitor purus eget leo suscipit sed posuere ligula gravida. In mollis velit quis leo pharetra gravida. Ut libero nisi,
 204 elementum sed varius tincidunt, hendrerit ut dui. Duis sit amet ante eget velit dictum ultrices. Nulla tempus, lacus eu dignissim
 205 feugiat, turpis mauris volutpat urna, quis commodo lorem augue id justo. Aenean consequat interdum sapien, sit amet
 206 imperdiet ante dapibus at. Pellentesque viverra sagittis tincidunt. Quisque rhoncus varius magna, sit amet rutrum arcu
 207 tincidunt eget. Etiam a lacus nec mauris interdum luctus sed in lacus. Ut pulvinar, augue at dictum blandit, nisl massa pretium
 208 ligula, in iaculis nulla nisi iaculis nunc.
 209
 210 Vivamus id eros nunc. Cras facilisis iaculis ante sit amet consequat. Nunc vehicula imperdiet sem, ac vehicula neque
 211 condimentum sed. Phasellus metus lacus, molestie ullamcorper imperdiet in, condimentum ut tellus. Nullam dignissim dui ut
 212 enim ullamcorper in tempus risus posuere. Ut volutpat enim eleifend diam convallis tristique. Proin porttitor augue sed sapien
 213 sagittis quis facilisis purus sodales. Integer auctor dolor rhoncus nisl consequat adipiscing. Aliquam eget ante sit amet quam
 214 porta eleifend.