test.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use constant true  => 1;
   6 use constant false => 0;
   7
   8 use File::Temp qw(tempfile tempdir tmpnam);
   9 use IPC::Open3 qw(open3);
  10 use Symbol qw(gensym);
  11 use TAP::Harness;
  12 use Test::More;
  13
  14 my $tests = 25;
  15
  16 my %BUF_SIZE = (
  17    normal => 1024,
  18    short  => 10,
  19 );
  20 my $source = 'colorize.c';
  21 my $compiler_flags = '-ansi -pedantic -Wall -Wextra -Wformat -Wswitch-default -Wuninitialized -Wunused -Wno-unused-function -Wno-unused-parameter';
  22
  23 my $write_to_tmpfile = sub
  24 {
  25     my ($content) = @_;
  26
  27     my ($fh, $tmpfile) = tempfile(UNLINK => true);
  28     print {$fh} $content;
  29     close($fh);
  30
  31     return $tmpfile;
  32 };
  33
  34 {
  35     my @tests = glob('t/*.t');
  36     my $harness = TAP::Harness->new;
  37     $harness->runtests(@tests);
  38 }
  39
  40 plan tests => $tests;
  41
  42 SKIP: {
  43     skip "$source does not exist", $tests unless -e $source;
  44
  45     my $binary = tmpnam();
  46     skip 'compiling failed', $tests unless system("gcc $compiler_flags -o $binary $source") == 0;
  47     unlink $binary;
  48
  49     my $program = tmpnam();
  50     skip 'compiling failed (normal)', $tests unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{normal} -o $program $source") == 0;
  51
  52     is(system("$program --help >/dev/null 2>&1"),    0, 'exit value for help screen');
  53     is(system("$program --version >/dev/null 2>&1"), 0, 'exit value for version data');
  54
  55     my $run_program_fail = sub
  56     {
  57         my ($program, $args, $message) = @_;
  58
  59         my @args = split /\s+/, $args;
  60
  61         my $err = gensym;
  62
  63         my $pid = open3(gensym, gensym, $err, $program, @args);
  64         waitpid($pid, 0);
  65
  66         my $output = do { local $/; <$err> };
  67
  68         return ($? >> 8 == 1 && $output =~ /$message/) ? true : false;
  69     };
  70
  71     {
  72         my $ok = true;
  73
  74         my $file = $write_to_tmpfile->('abc');
  75         my $dir  = tempdir(CLEANUP => true);
  76
  77         $ok &= $run_program_fail->($program, '--exclude-random=random', 'must be provided a plain color');
  78         $ok &= $run_program_fail->($program, '--clean --clean-all',     'mutually exclusive');
  79         $ok &= $run_program_fail->($program, '--clean file1 file2',     'more than one file');
  80         $ok &= $run_program_fail->($program, '--clean-all file1 file2', 'more than one file');
  81         $ok &= $run_program_fail->($program, '- file',                  'hyphen cannot be used as color string');
  82         $ok &= $run_program_fail->($program, '-',                       'hyphen must be preceeded by color string');
  83         $ok &= $run_program_fail->($program, "$file file",              'cannot be used as color string');
  84         $ok &= $run_program_fail->($program, "$file",                   'must be preceeded by color string');
  85         $ok &= $run_program_fail->($program, "$dir",                    'is not a valid file type');
  86         $ok &= $run_program_fail->($program, '/black',                  'foreground color missing');
  87         $ok &= $run_program_fail->($program, 'white/',                  'background color missing');
  88         $ok &= $run_program_fail->($program, 'white/black/yellow',      'one color pair allowed only');
  89         $ok &= $run_program_fail->($program, 'y3llow',                  'cannot be made of non-alphabetic characters');
  90         $ok &= $run_program_fail->($program, 'yEllow',                  'cannot be in mixed lower/upper case');
  91         $ok &= $run_program_fail->($program, 'None',                    'cannot be bold');
  92         $ok &= $run_program_fail->($program, 'white/Black',             'cannot be bold');
  93
  94         foreach my $color_pair (qw(random/none random/default none/random default/random)) {
  95             $ok &= $run_program_fail->($program, $color_pair, 'cannot be combined with');
  96         }
  97
  98         ok($ok, 'exit messages/values for failures');
  99     }
 100
 101     is(qx(echo    "hello world" | $program none/none), "hello world\n", 'line read from stdin with newline');
 102     is(qx(echo -n "hello world" | $program none/none), "hello world",   'line read from stdin without newline');
 103
 104     my $text = do { local $/; <DATA> };
 105
 106     my $infile1 = $write_to_tmpfile->($text);
 107
 108     is_deeply([split /\n/, qx(cat $infile1 | $program none/none)], [split /\n/, $text], 'text read from stdin');
 109     is_deeply([split /\n/, qx($program none/none $infile1)],       [split /\n/, $text], 'text read from file');
 110
 111     {
 112         my @fg_colors = (30..37, 39);
 113         my @bg_colors = (40..47, 49);
 114
 115         my @bold_colors = map "1;$_", @fg_colors;
 116
 117         my @values = (@fg_colors, @bg_colors, @bold_colors, 0);
 118
 119         my $ok = true;
 120         foreach my $value (@values) {
 121             $ok &= qx(echo -n "\e[${value}m" | $program --clean) eq '';
 122         }
 123         ok($ok, 'clean color sequences');
 124     }
 125
 126     my $check_clean = sub
 127     {
 128         my ($type) = @_;
 129
 130         my $switch = "--$type";
 131
 132         is(qx(echo -n "\e[35mhello\e[0m \e[36mworld\e[0m" | $program $switch),       'hello world', "$type colored words");
 133         is(qx(echo -n "hello world" | $program Magenta | $program $switch),          'hello world', "$type colored line");
 134         is_deeply([split /\n/, qx($program cyan $infile1 | $program $switch)], [split /\n/, $text], "$type colored text");
 135
 136         ok(qx(echo -n "\e[\e[33m" | $program $switch) eq "\e[", "$type with invalid sequence");
 137     };
 138
 139     $check_clean->($_) foreach qw(clean clean-all);
 140
 141     is(qx(echo -n "\e[4munderline\e[24m" | $program --clean-all), 'underline', 'clean-all color sequences');
 142
 143     my $check_clean_buf = sub
 144     {
 145         my ($program_buf, $type) = @_;
 146
 147         my $switch = "--$type";
 148
 149         # Check that line chunks are merged when cleaning text
 150         my $short_text = 'Linux dev 2.6.32-5-openvz-686 #1 SMP Sun Sep 23 11:40:07 UTC 2012 i686 GNU/Linux';
 151         is(qx(echo -n "$short_text" | $program_buf $switch), $short_text, "merge ${\length $short_text} bytes (BUF_SIZE=$BUF_SIZE{short}, $type)");
 152     };
 153
 154     SKIP: {
 155         my $program_buf = tmpnam();
 156         skip 'compiling failed (short buffer)', 2 unless system("gcc -DTEST -DBUF_SIZE=$BUF_SIZE{short} -o $program_buf $source") == 0;
 157         $check_clean_buf->($program_buf, $_) foreach qw(clean clean-all);
 158         unlink $program_buf;
 159     }
 160
 161     my $repeated = join "\n", ($text) x 7;
 162     my $infile2  = $write_to_tmpfile->($repeated);
 163
 164     is_deeply([split /\n/, qx(cat $infile2 | $program none/none)], [split /\n/, $repeated], "read ${\length $repeated} bytes (BUF_SIZE=$BUF_SIZE{normal})");
 165
 166     {
 167         my $colored_text = qx(echo "foo bar baz" | $program red);
 168         my $sequences = 0;
 169         $sequences++ while $colored_text =~ /\e\[\d+m/g;
 170         is($sequences, 2, 'count of sequences printed');
 171     }
 172
 173     is(qx(echo -n "hello\nworld\r\n" | $program none/none), "hello\nworld\r\n", 'stream mode');
 174
 175     is(system("echo \"hello world\" | $program random --exclude-random=black >/dev/null 2>&1"), 0, 'switch exclude-random');
 176
 177     SKIP: {
 178         skip 'valgrind not found', 1 unless system('which valgrind >/dev/null 2>&1') == 0;
 179         like(qx(valgrind $program none/none $infile1 2>&1 >/dev/null), qr/no leaks are possible/, 'valgrind memleaks');
 180     }
 181
 182     {
 183         my $debug = tmpnam();
 184         is(system("gcc -DDEBUG -o $debug $source"), 0, 'debugging build');
 185         unlink $debug if -e $debug;
 186     }
 187
 188     print <<'EOT';
 189 Colors
 190 ======
 191 EOT
 192     foreach my $color (qw(none black red green yellow blue magenta cyan white default random)) {
 193         system("echo $color | $program $color");
 194         next if $color eq 'none';
 195         my $bold_color = ucfirst $color;
 196         system("echo $bold_color | $program $bold_color");
 197     }
 198
 199     unlink $program;
 200 };
 201
 202 __DATA__
 203 Lorem ipsum dolor sit amet, consectetur adipiscing elit. Vivamus urna mauris, ultricies faucibus placerat sit amet, rutrum eu
 204 nisi. Quisque dictum turpis non augue iaculis tincidunt nec a arcu. Donec euismod sapien ac dui blandit et adipiscing risus
 205 semper. Sed ornare ligula magna, vitae molestie eros. Praesent ligula est, euismod a luctus non, porttitor quis nunc. Fusce vel
 206 imperdiet turpis. Proin vitae mauris neque, fringilla vestibulum sapien. Pellentesque vitae nibh ipsum, non cursus diam. Cras
 207 vitae ligula mauris. Etiam tortor enim, varius nec adipiscing sed, lobortis et quam. Quisque convallis, diam sagittis adipiscing
 208 adipiscing, mi nibh fermentum sapien, et iaculis nisi sem sit amet odio. Cras a tortor at nibh tristique vehicula dapibus eu velit.
 209
 210 Vivamus porttitor purus eget leo suscipit sed posuere ligula gravida. In mollis velit quis leo pharetra gravida. Ut libero nisi,
 211 elementum sed varius tincidunt, hendrerit ut dui. Duis sit amet ante eget velit dictum ultrices. Nulla tempus, lacus eu dignissim
 212 feugiat, turpis mauris volutpat urna, quis commodo lorem augue id justo. Aenean consequat interdum sapien, sit amet
 213 imperdiet ante dapibus at. Pellentesque viverra sagittis tincidunt. Quisque rhoncus varius magna, sit amet rutrum arcu
 214 tincidunt eget. Etiam a lacus nec mauris interdum luctus sed in lacus. Ut pulvinar, augue at dictum blandit, nisl massa pretium
 215 ligula, in iaculis nulla nisi iaculis nunc.
 216
 217 Vivamus id eros nunc. Cras facilisis iaculis ante sit amet consequat. Nunc vehicula imperdiet sem, ac vehicula neque
 218 condimentum sed. Phasellus metus lacus, molestie ullamcorper imperdiet in, condimentum ut tellus. Nullam dignissim dui ut
 219 enim ullamcorper in tempus risus posuere. Ut volutpat enim eleifend diam convallis tristique. Proin porttitor augue sed sapien
 220 sagittis quis facilisis purus sodales. Integer auctor dolor rhoncus nisl consequat adipiscing. Aliquam eget ante sit amet quam
 221 porta eleifend.