client.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright (c) 2013 Michel Ketterle, Steven Schubiger
   4 #
   5 # This file is part of distdns.
   6 #
   7 # distdns is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # distdns is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with distdns.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 use warnings;
  22 use constant false => 0;
  23
  24 use Config::Tiny;
  25 use Digest::MD5 qw(md5_hex);
  26 use Fcntl ':flock';
  27 use File::Spec::Functions qw(catfile rel2abs);
  28 use FindBin qw($Bin);
  29 use Getopt::Long qw(:config no_auto_abbrev no_ignore_case);
  30 use JSON qw(decode_json);
  31 use LWP::UserAgent;
  32 use Sys::Hostname qw(hostname);
  33 use Tie::File;
  34
  35 my $VERSION = '0.05';
  36
  37 my $conf_file = catfile($Bin, 'client.conf');
  38
  39 sub _die { die "$0: [client] $_[0]" }
  40
  41 sub usage
  42 {
  43     print <<"USAGE";
  44 Usage: $0
  45     -d, --debug    server debugging
  46     -h, --help     this help screen
  47     -i, --init     initialize session data
  48 USAGE
  49     exit;
  50 }
  51
  52 my %opts;
  53 GetOptions(\%opts, qw(d|debug h|help i|init)) or usage();
  54 usage() if $opts{h};
  55
  56 my $config = Config::Tiny->new;
  57    $config = Config::Tiny->read($conf_file);
  58
  59 my $get_config_opts = sub
  60 {
  61     my ($section, $options) = @_;
  62
  63     _die "Section $section missing in $conf_file\n" unless exists $config->{$section};
  64
  65     my %options;
  66     @options{@$options} = @{$config->{$section}}{@$options};
  67
  68     foreach my $option (@$options) {
  69         _die "Option $option not set in $conf_file\n" unless defined $options{$option} && length $options{$option};
  70     }
  71
  72     return @options{@$options};
  73 };
  74
  75 my ($hosts_file, $session_file) = map rel2abs($_, $Bin), $get_config_opts->('path', [ qw(hosts_file session_file) ]);
  76
  77 my ($server_url)  = $get_config_opts->('url',  [ qw(server_url) ]);
  78 my ($netz, $name) = $get_config_opts->('data', [ qw(netz name)  ]);
  79
  80 my $save_session = sub
  81 {
  82     my ($session) = @_;
  83
  84     open(my $fh, '>', $session_file) or _die "Cannot open $session_file for writing: $!\n";
  85     print {$fh} "$session\n";
  86     close($fh);
  87 };
  88
  89 my $get_session = sub
  90 {
  91     open(my $fh, '<', $session_file) or _die "Cannot open $session_file for reading: $!\nPerhaps try running --init\n";
  92     my $session = do { local $/; <$fh> };
  93     chomp $session;
  94     close($fh);
  95
  96     return $session;
  97 };
  98
  99 my $session = $opts{i} ? substr(md5_hex(md5_hex(time() . {} . rand() . $$)), 0, 32) : $get_session->();
 100
 101 my %params = (
 102     netz    => $netz,
 103     pc      => hostname(),
 104     name    => $name,
 105     debug   => $opts{d} || false,
 106     init    => $opts{i} || false,
 107     session => $session,
 108 );
 109
 110 my $ua = LWP::UserAgent->new;
 111
 112 my $response = $ua->post($server_url, \%params);
 113
 114 if ($response->is_success) {
 115     my $data;
 116
 117     eval {
 118         $data = decode_json($response->decoded_content);
 119     } or exit;
 120
 121     die "$0: [server] $data->{error}" if defined $data->{error};
 122
 123     $save_session->($session) if $opts{i};
 124
 125     my %list;
 126     foreach my $entry (@{$data->{entries}}) {
 127         my $host = "$entry->{ip}\t" . join '.', @$entry{qw(name pc netz)};
 128         push @{$list{$entry->{netz}}}, $host;
 129     }
 130
 131     my $o = tie my @hosts, 'Tie::File', $hosts_file or _die "Cannot tie $hosts_file: $!\n";
 132     $o->flock(LOCK_EX);
 133
 134     foreach my $network (keys %list) {
 135         my %indexes;
 136         for (my $i = 0; $i < @hosts; $i++) {
 137             if ($hosts[$i] =~ /^\#$network\#$/i) {
 138                 $indexes{start} = $i;
 139             }
 140             elsif (exists $indexes{start} && $hosts[$i] =~ /^\#\/$network\#$/i) {
 141                 $indexes{end} = $i;
 142                 my $count = ($indexes{end} - $indexes{start} > 1)
 143                   ? $indexes{end} - $indexes{start} - 1
 144                   : 0;
 145                 splice @hosts, $indexes{start} + 1, $count, @{$list{$network}};
 146                 last;
 147             }
 148         }
 149     }
 150
 151     undef $o;
 152     untie @hosts;
 153 }
 154 else {
 155     warn $response->status_line, "\n";
 156 }