test.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use lib qw(lib);
   6 use constant true  => 1;
   7 use constant false => 0;
   8
   9 use Colorize::Common qw(:defaults $compiler_flags %BUF_SIZE $valgrind_command $write_to_tmpfile);
  10 use File::Find;
  11 use File::Temp qw(tmpnam);
  12 use Getopt::Long qw(:config no_auto_abbrev no_ignore_case);
  13 use Test::Harness qw(runtests);
  14 use Test::More;
  15
  16 my $tests = 32;
  17
  18 my $valgrind_cmd = '';
  19 {
  20     my ($regular, $valgrind);
  21     GetOptions(regular => \$regular, valgrind => \$valgrind) or exit;
  22     if (not $regular || $valgrind) {
  23         die "$0: neither --regular nor --valgrind specified, exiting\n";
  24     }
  25     elsif ($regular && $valgrind) {
  26         die "$0: both --regular and --valgrind specified, exiting\n";
  27     }
  28     $valgrind_cmd = "$valgrind_command " if $valgrind;
  29 }
  30
  31 {
  32     my @test_files;
  33     find ({ wanted => sub { push @test_files, $File::Find::name if /\.t$/ } }, 't');
  34     eval { runtests(sort @test_files) } or warn $@;
  35 }
  36
  37 plan tests => $tests;
  38
  39 SKIP: {
  40     skip "$source does not exist", $tests unless -e $source;
  41
  42     my $binary = tmpnam();
  43     skip 'compiling failed', $tests unless system("$compiler $compiler_flags -o $binary $source") == 0;
  44     unlink $binary;
  45
  46     my $program = tmpnam();
  47     skip 'compiling failed (normal)', $tests unless system("$compiler -DTEST -DBUF_SIZE=$BUF_SIZE{normal} -o $program $source") == 0;
  48
  49     is(system("$valgrind_cmd$program --help >/dev/null"),    0, 'exit value for help screen');
  50     is(system("$valgrind_cmd$program --version >/dev/null"), 0, 'exit value for version data');
  51
  52     is(qx(printf '%s\n' "hello world" | $valgrind_cmd$program none/none), "hello world\n", 'line read from stdin with newline');
  53     is(qx(printf  %s    "hello world" | $valgrind_cmd$program none/none), "hello world",   'line read from stdin without newline');
  54
  55     my $text = do { local $/; <DATA> };
  56
  57     my $infile1 = $write_to_tmpfile->($text);
  58
  59     is_deeply([split /\n/, qx(cat $infile1 | $valgrind_cmd$program none/none)], [split /\n/, $text], 'text read from stdin');
  60     is_deeply([split /\n/, qx($valgrind_cmd$program none/none $infile1)],       [split /\n/, $text], 'text read from file');
  61
  62     {
  63         my @fg_colors = (30..37, 39);
  64         my @bg_colors = (40..47, 49);
  65
  66         my @bold_colors = map "1;$_", @fg_colors;
  67
  68         my @values = (@fg_colors, @bg_colors, @bold_colors, 0);
  69
  70         my $ok = true;
  71         foreach my $value (@values) {
  72             $ok &= qx(printf %s "\e[${value}m" | $valgrind_cmd$program --clean) eq '';
  73         }
  74         ok($ok, 'clean color sequences');
  75     }
  76
  77     my $check_clean = sub
  78     {
  79         my ($type) = @_;
  80
  81         my $switch = "--$type";
  82
  83         is(qx(printf %s "\e[35mhello\e[0m \e[36mworld\e[0m" | $valgrind_cmd$program $switch),     'hello world', "$type colored words");
  84         is(qx(printf %s "hello world" | $program Magenta | $valgrind_cmd$program $switch),        'hello world', "$type colored line");
  85         is_deeply([split /\n/, qx($program cyan $infile1 | $valgrind_cmd$program $switch)], [split /\n/, $text], "$type colored text");
  86
  87         {
  88             my @attrs = qw(bold underscore blink reverse concealed);
  89
  90             my $ok = true;
  91             foreach my $attr (@attrs) {
  92                 $ok &= qx(printf %s "$attr" | $program green --attr=$attr | $valgrind_cmd$program $switch) eq $attr;
  93             }
  94             ok($ok, "$type attribute");
  95
  96             my $attrs = join ',', @attrs;
  97             is(qx(printf %s "$attrs" | $program green --attr=$attrs | $valgrind_cmd$program $switch), $attrs, "$type attributes");
  98         }
  99
 100         ok(qx(printf %s "\e[\e[33m" | $valgrind_cmd$program $switch) eq "\e[", "$type with invalid sequence");
 101
 102         {
 103             my $ok = true;
 104             foreach my $option (qw(--attr=bold --exclude-random=black --omit-color-empty)) {
 105                 $ok &= qx($valgrind_cmd$program $option $switch $infile1 2>&1 >/dev/null) =~ /switch has no meaning with/;
 106             }
 107             ok($ok, "$type strict options");
 108         }
 109     };
 110
 111     $check_clean->($_) foreach qw(clean clean-all);
 112
 113     is(qx(printf %s "\e[4munderline\e[24m" | $valgrind_cmd$program --clean-all), 'underline', 'clean-all color sequences');
 114
 115     my $check_clean_buf = sub
 116     {
 117         my ($program_buf, $type) = @_;
 118
 119         my $switch = "--$type";
 120
 121         # Check that line chunks are printed when cleaning text without sequences
 122         my $short_text = 'Linux dev 2.6.32-5-openvz-686 #1 SMP Sun Sep 23 11:40:07 UTC 2012 i686 GNU/Linux';
 123         is(qx(printf %s "$short_text" | $valgrind_cmd$program_buf $switch), $short_text, "print ${\length $short_text} bytes (BUF_SIZE=$BUF_SIZE{short}, $type)");
 124     };
 125
 126     SKIP: {
 127         my $program_buf = tmpnam();
 128         skip 'compiling failed (short buffer)', 2 unless system("$compiler -DTEST -DBUF_SIZE=$BUF_SIZE{short} -o $program_buf $source") == 0;
 129         $check_clean_buf->($program_buf, $_) foreach qw(clean clean-all);
 130         unlink $program_buf;
 131     }
 132
 133     my $repeated = join "\n", ($text) x 7;
 134     my $infile2  = $write_to_tmpfile->($repeated);
 135
 136     is_deeply([split /\n/, qx(cat $infile2 | $valgrind_cmd$program none/none)], [split /\n/, $repeated], "read ${\length $repeated} bytes (BUF_SIZE=$BUF_SIZE{normal})");
 137
 138     {
 139         my $colored_text = qx(printf '%s\n' "foo bar baz" | $valgrind_cmd$program red);
 140         my $sequences = 0;
 141         $sequences++ while $colored_text =~ /\e\[\d+m/g;
 142         is($sequences, 2, 'count of sequences printed');
 143     }
 144
 145     {
 146         # Check that a 'none' foreground color (with a background color present)
 147         # will be substituted by 'default'.
 148         my $colored_text = qx(printf %s "foo bar baz" | $valgrind_cmd$program none/black);
 149         is($colored_text, "\e[40m\e[39mfoo bar baz\e[0m", 'no color sequences printed');
 150     }
 151
 152     is(qx(printf %s "hello\nworld\r\n" | $valgrind_cmd$program none/none), "hello\nworld\r\n", 'stream mode');
 153
 154     is(system(qq(printf '%s\n' "hello world" | $valgrind_cmd$program random --exclude-random=black >/dev/null)), 0, 'switch exclude-random');
 155
 156     {
 157         my $infile = $write_to_tmpfile->("foo\n\nbar");
 158         is_deeply([split /\n/, qx($valgrind_cmd$program yellow --omit-color-empty $infile)],
 159                   [split /\n/, "\e[33mfoo\e[0m\n\n\e[33mbar\e[0m"],
 160                   'switch omit-color-empty');
 161     }
 162
 163     SKIP: {
 164         skip 'valgrind not found', 1 unless system('which valgrind >/dev/null 2>&1') == 0;
 165         like(qx(valgrind $program none/none $infile1 2>&1 >/dev/null), qr/no leaks are possible/, 'valgrind memleaks');
 166     }
 167
 168     {
 169         my $debug = tmpnam();
 170         is(system("$compiler -DDEBUG -o $debug $source"), 0, 'debugging build');
 171         unlink $debug if -e $debug;
 172     }
 173
 174     print <<'EOT';
 175 Colors
 176 ======
 177 EOT
 178     foreach my $color (qw(none black red green yellow blue magenta cyan white default random)) {
 179         system(qq(printf '%s\n' "$color" | $program $color));
 180         next if $color eq 'none';
 181         my $bold_color = ucfirst $color;
 182         system(qq(printf '%s\n' "$bold_color" | $program $bold_color));
 183     }
 184
 185     print <<'EOT';
 186 Attributes
 187 ==========
 188 EOT
 189     foreach my $attr (qw(bold underscore blink reverse concealed)) {
 190         system(qq(printf '%s\n' "$attr" | $program green --attr=$attr));
 191     }
 192
 193     unlink $program;
 194 };
 195
 196 __DATA__
 197 Lorem ipsum dolor sit amet, consectetur adipiscing elit. Vivamus urna mauris, ultricies faucibus placerat sit amet, rutrum eu
 198 nisi. Quisque dictum turpis non augue iaculis tincidunt nec a arcu. Donec euismod sapien ac dui blandit et adipiscing risus
 199 semper. Sed ornare ligula magna, vitae molestie eros. Praesent ligula est, euismod a luctus non, porttitor quis nunc. Fusce vel
 200 imperdiet turpis. Proin vitae mauris neque, fringilla vestibulum sapien. Pellentesque vitae nibh ipsum, non cursus diam. Cras
 201 vitae ligula mauris. Etiam tortor enim, varius nec adipiscing sed, lobortis et quam. Quisque convallis, diam sagittis adipiscing
 202 adipiscing, mi nibh fermentum sapien, et iaculis nisi sem sit amet odio. Cras a tortor at nibh tristique vehicula dapibus eu velit.
 203
 204 Vivamus porttitor purus eget leo suscipit sed posuere ligula gravida. In mollis velit quis leo pharetra gravida. Ut libero nisi,
 205 elementum sed varius tincidunt, hendrerit ut dui. Duis sit amet ante eget velit dictum ultrices. Nulla tempus, lacus eu dignissim
 206 feugiat, turpis mauris volutpat urna, quis commodo lorem augue id justo. Aenean consequat interdum sapien, sit amet
 207 imperdiet ante dapibus at. Pellentesque viverra sagittis tincidunt. Quisque rhoncus varius magna, sit amet rutrum arcu
 208 tincidunt eget. Etiam a lacus nec mauris interdum luctus sed in lacus. Ut pulvinar, augue at dictum blandit, nisl massa pretium
 209 ligula, in iaculis nulla nisi iaculis nunc.
 210
 211 Vivamus id eros nunc. Cras facilisis iaculis ante sit amet consequat. Nunc vehicula imperdiet sem, ac vehicula neque
 212 condimentum sed. Phasellus metus lacus, molestie ullamcorper imperdiet in, condimentum ut tellus. Nullam dignissim dui ut
 213 enim ullamcorper in tempus risus posuere. Ut volutpat enim eleifend diam convallis tristique. Proin porttitor augue sed sapien
 214 sagittis quis facilisis purus sodales. Integer auctor dolor rhoncus nisl consequat adipiscing. Aliquam eget ante sit amet quam
 215 porta eleifend.